Sign in to follow this  
Followers 0
PoweredByte

ExileMod Jump Animation possible?

4 posts in this topic

Hey guys, it is possible to make a Jump Animation like in Altis Life?

Share this post


Link to post
Share on other sites
9 minutes ago, PoweredByte said:

Hey guys, it is possible to make a Jump Animation like in Altis Life?

There's an old jump animate script that I'm sure could work with some configuration. I'm pretty sure the weight system may cause some issues with the script working right out of the box. While you'd need to do some tweaking for it to work, the animation values are included in the script.

 

https://forums.bistudio.com/topic/150917-realistic-jumping-script/

Share this post


Link to post
Share on other sites
Advertisement

Been working with this...but no success yet. A3Wasteland has another version of this without fatigue but haven't had any success with it either.

Share this post


Link to post
Share on other sites

This is the one we used to use for Wasteland:

//////////////////////////////////////////////////////////////////
// Script File for [Arma 3] - detect_key_input.sqf
// Created by: Das Attorney
// Modified by: AgentRev
//////////////////////////////////////////////////////////////////

#define HORDE_JUMPMF_SLOWING_MULTIPLIER 0.75

private ["_pressedKey", "_handled", "_move", "_moveM", "_moveP"];
_pressedKey = _this select 1;
_handled = false;

if (_pressedKey in actionKeys "GetOver") then
{
	if (horde_jumpmf_var_jumping) exitWith
	{
		_handled = true;
	};

	if (vehicle player == player) then
	{
		_move = animationState player;
		_moveM = toLower (_move select [8,4]);
		_moveP = toLower (_move select [4,4]);

		if (_moveM in ["mrun","meva"] && _moveP in ["perc","pknl"] && getFatigue player < 0.6 && isTouchingGround player) then
		{
			horde_jumpmf_var_jumping = true;

			_move spawn
			{
				private ["_prevMove", "_prevVel", "_fatigue", "_load"];

				_prevMove = _this;
				_prevVel = velocity player;
				_fatigue = getFatigue player;
				_load = loadAbs player;

				[player, "AovrPercMrunSrasWrflDf"] call switchMoveGlobal;

				waitUntil
				{
					player setFatigue (_fatigue + 0.05 + (_load / 5000));
					player setVelocity
					[
						(_prevVel select 0) * HORDE_JUMPMF_SLOWING_MULTIPLIER,
						(_prevVel select 1) * HORDE_JUMPMF_SLOWING_MULTIPLIER,
						((velocity player) select 2) min 1
					];
					(animationState player != "AovrPercMrunSrasWrflDf")
				};

				[player, _prevMove] call switchMoveGlobal;
				player setVelocity
				[
					_prevVel select 0,
					_prevVel select 1,
					(velocity player) select 2
				];

				sleep 0.5; // Cooldown

				horde_jumpmf_var_jumping = false;
			};

			_handled = true;
		};
	};
};

_handled

 

//////////////////////////////////////////////////////////////////
// Script File for [Arma 3] - init.sqf
// Created by: Das Attorney
// Modified by: AgentRev
//////////////////////////////////////////////////////////////////

if (!hasInterface) exitWith {};

horde_jumpmf_var_jumping = false;
horde_jumpmf_fnc_detect_key_input = "addons\JumpMF\detect_key_input.sqf" call mf_compile;

waitUntil {!isNull findDisplay 46};
(findDisplay 46) displayAddEventHandler ["KeyDown", horde_jumpmf_fnc_detect_key_input];

 

 

Edit:  Server used CBA to for this and others.

Edited by Thrash

Share this post


Link to post
Share on other sites
Advertisement

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0

  • Recently Browsing   0 members

    No registered users viewing this page.