red_ned

Help required to finish

16 posts in this topic

I started writing a mission for Tanoa before I had to shut down for a while and I never got 1 thing working on it as its a really complex mission even for me.

Anyone know how to fix my Heli patrol - looking towards @Defent or @eraser1:)

all the usual variable stuff at start

defining heli type, spawn and drop zone

Quote

//define heli start, drop and class
_spawnPos = [5500,10000,350];
_dropPoint = [5765.37,10369,250];
_heliClass = ["Exile_Chopper_Huey_Armed_Green"];

Spawn heli

Quote

// add heli
_heli =  [
    _group2,
    "random",
    _difficulty,
    _side,
    _dropPoint,
    true,
    6,
    true,
    _heliClass,
    _spawnPos
   ] call DMS_fnc_SpawnHeliReinforcement; 

 

clean up and marker inclusion

Quote

// Define mission-spawned objects and loot values with vehicle
_missionObjs = [
     _staticGuns+_baseObjs+[_veh]+[_heli],          // static gun(s). Road blocks. Patrol vehicles
     [_vehicle],               // vehicle prize
     [[_crate0,_crate_loot_values0],[_crate1,_crate_loot_values1]]  // crates
    ]; 

I think this may be the fixed version but could anyone verify this would work?

I will be needing someone to test it out too :) 

cheers

Share this post


Link to post
Share on other sites

Hi @red_ned

Big fan of your work. I have had more luck with heli reinforcements on static missions, no luck with bandit missions.

I got all the code ideas from this post by @eraser1  & @[RG] Salutesh

Here is the code:

Spoiler

_pos = [INSERT POSITION HERE];
_group =
[
	_pos,
	1,
	"random",
	"random",
	"bandit"
] call DMS_fnc_SpawnAIGroup;
[
	_group,
	"random",
	"difficult",
	"bandit",
	_pos,
	true,
	99,
	true
] call DMS_fnc_SpawnHeliReinforcement;

and here the key found in fn_SpawnHeliReinforcement.sqf:

Spoiler

[
        _AIGroup,                       // GROUP: The group to which the heli will be assigned.
        _class,                         // STRING: The class of AI to spawn in the heli.
        _difficulty,                    // STRING: The difficulty of the AI to spawn in the heli.
        _side,                          // STRING: The "side" that the AI are on.
        _dropPoint,                     // OBJECT or ARRAY (Position2D or 3D): The location to drop the reinforcements at.
        _ejectFFVGunners,               // BOOLEAN: Whether or not to eject Fire-From-Vehicle (FFV) gunners.
        _maxJumpers,                    // SCALAR: Maximum number of AI to eject from the aircraft. Set to a really high # to ignore (like 999).
        _remainAsGunship,               // BOOLEAN: Whether or not to keep the heli flying around as a gunship.
        _heliClass,                     // STRING (OPTIONAL): The classname of the heli to spawn.
        _spawnPos                       // ARRAY (OPTIONAL - Position2D or 3D): The position for the heli to spawn at.
    ] call DMS_fnc_SpawnHeliReinforcement;

I would recommend placing a helipad at the mission. It encourages the heli to land & gives players a chance to take out the pilot.

I change the last "true" to "false" (remain as a gunship). You end up getting a squadron of helis doing laps around the map aimlessly.

@[RG] Salutesh used a diffent code in his legendary Fortress mission.

Here is the heli code:

Spoiler


// Define the group reinforcements
_groupReinforcementsInfo =
[
    [
        _groupHeli,                                // pass the group
        [
            [
                _AIMaxReinforcementsWaves,        // Amount of reinfocements waves (defined in difficulty selection).
                0
            ],
            [
                _AIMaxReinforcements,            // Maximum units that can be given as reinforcements (defined in difficulty selection).
                0
            ]
        ],
        [
            _AIdelay,                            // The delay between reinforcements. >> you can change this in difficulty settings
            diag_tickTime
        ],
        _AISoldierSpawnLocationsHeli,
        "random",
        _difficulty,
        _side,
        "heli_troopers",                                // STRING: How the AI group should be managed. Supported types: "playernear", "maintain", "reinforce", "increasing_resistance", "armed_vehicle"
        [
            3,                                            // SCALAR: If the AI Group has fewer than "_AICount" living units, then the group will receive reinforcements.
            "false",                                       // BOOLEAN: Whether or not to eject Fire-From-Vehicle (FFV) gunners.
            5,                                            // SCALAR: Maximum number of AI to eject from the aircraft. Set to a really high # to ignore (like 999).
            "false",                                       // BOOLEAN: Whether or not to keep the heli flying around as a gunship.
            [12141.1,2498.89,0],                           // OBJECT or ARRAY (OPTIONAL - Position2D or 3D): The location to drop the reinforcements at. The drop point will default to the group leader.
            "Exile_Chopper_Huey_Armed_Desert"             // STRING (OPTIONAL): The classname of the heli to spawn.
        ]
    ]
];

and here is the whole raid fortress mission:

Spoiler

/*
    "The Fortress" v2.0 Static Raid Mission Tanoa for DMS Exile
    
    Needed a3_ims addon by Salutesh to work as it should.
    Created by [RG] Salutesh
    www.reality-gaming.eu
    
    Includes much love to the AI enviroment:
    - Static NPC group spawns with ai behavior, waypoints and formations.
    - Patrol group that move in a cycle around in the fortress area.
    - Static guns spawns.
    - Helicopter reinfocements.
*/

private ["_AICount", "_AIMaxReinforcements", "_AIMaxReinforcementsWaves", "_AIdelay", "_staticguns", "_missionObjs", "_crate", "_crate_loot_values", "_crate_weapons", "_crate_items", "_crate_backpacks", "_difficulty", "_PossibleDifficulty", "_msgWIN"];

// For logging purposes
_num = DMS_MissionCount;

// Set mission side (only "bandit" is supported for now)
_side = "bandit";

_pos = [12103,2486,0];                 // Center position of the area

if ([_pos,DMS_StaticMinPlayerDistance] call DMS_fnc_IsPlayerNearby) exitWith {"delay"};

_difficulty = "hardcore";

_AIMaxReinforcementsWaves = 1;
_AIMaxReinforcements = 5;
_AIdelay = 10;

private _temp = DMS_ai_use_launchers;
DMS_ai_use_launchers = true;

// Definethe amount of units and spawn locations for AI Soldiers. These will be used for the initial spawning of AI as well as reinforcements.
// The center spawn location is added 3 times so at least 3 AI will spawn initially at the center location, and so that future reinforcements are more likely to spawn at the center.
_AICount1 = 2;
_AISoldierSpawnLocations1 =
[
    [12044.6,2388.7,18.1043],
    [12039,2393.5,17.8751]    
];

_AICount2 = 2;
_AISoldierSpawnLocations2 =
[
    [12126,2453.96,0],
    [12132.1,2457.75,0]
];

_AICount3 = 2;
_AISoldierSpawnLocations3 =
[
    [12061.6,2408.75,0],
    [12132.2,2457.24,0]
];

_AICount4 = 3;
_AISoldierSpawnLocations4 =
[
    [12189.1,2452.46,3.06728],
    [12188.5,2456.66,3.14114],
    [12193.4,2459.34,3.06728]
];

_AICount5 = 2;
_AISoldierSpawnLocations5 =
[
    [12126.7,2490.34,0],
    [12126.1,2496.81,0]
];

_AICount6 = 2;
_AISoldierSpawnLocations6 =
[
    [12184.4,2567.41,17.8731],
    [12179.3,2575.06,17.8731]
];

_AICount7 = 3;
_AISoldierSpawnLocations7 =
[
    [12034.6,2558.85,3.12652],
    [12029.3,2560.47,2.92652],
    [12037.2,2562.26,3.12652]
];

_AICount8 = 1;
_AISoldierSpawnLocations8 =
[
    [12106.2,2516.74,4.57695]
];

_AICount9 = 2;
_AISoldierSpawnLocations9 =
[
    [12021.6,2450.42,0],
    [12017.6,2449.1,0]
];

_AICountPatrol = 3;
_AISoldierSpawnLocationsPatrol =
[
    [12165.9,2552.81,0],
    [12169.5,2552.86,0],
    [12164.8,2555.35,0]
];

_AICountHeli = 3;
_AISoldierSpawnLocationsHeli =
[
    [12086.5,2470.26,0],
    [12084.6,2467.62,0],
    [12083.4,2469.76,0]
];

// Spawn the Units
// First AI Group spawn.
_group1 =
[
    _AISoldierSpawnLocations1,        // Pass the regular spawn locations.
    _AICount1,                        // Ai count.
    _difficulty,                    // Set in difficulty select.
    "sniper",
    _side
] call DMS_fnc_SpawnAIGroup_MultiPos;

// Set first group units behavior
[
    _group1,                        // GROUP or OBJECT: Group or unit whose behavior is to be changed.
    [12044.6,2388.7,18.1043],        // ARRAY (positionATL): Location for the AI to guard.
    _difficulty,                    // STRING: Difficulty of the AI.
    "SAFE"                            // (OPTIONAL) STRING: AI Behavior. Refer to: https://community.bistudio.com/wiki/setBehaviour
] call DMS_fnc_SetGroupBehavior;
// Remove all previous waypoints for the first group.
for "_i" from count (waypoints _group1) to 1 step -1 do
{
    deleteWaypoint ((waypoints _group1) select _i);
};
// Give first group waypoints.
private _wp1 = _group1 addWaypoint [[12044.6,2388.7,18.1043],0];
_wp1 setWaypointType "HOLD";
// Let the Ai dont move from there positions.
doStop (units _group1);

// Second AI Group spawn.
_group2 = [_AISoldierSpawnLocations2, _AICount2, _difficulty, "assault", _side] call DMS_fnc_SpawnAIGroup_MultiPos;
// Set second group units behavior.
[_group2, [12060.6,2403.62,0], _difficulty, "SAFE"] call DMS_fnc_SetGroupBehavior;
// Remove all previous waypoints for the second group.
for "_i" from count (waypoints _group2) to 1 step -1 do
{
    deleteWaypoint ((waypoints _group2) select _i);
};
// Set second group formation.
//_group2 setFormation "COLUMN";
// Give second group waypoints.
private _wp2 = _group2 addWaypoint [[12060.6,2403.62,0],0];
_wp2 setWaypointType "SENTRY";

// Third AI Group spawn.
_group3 = [_AISoldierSpawnLocations3, _AICount3, _difficulty, "MG", _side] call DMS_fnc_SpawnAIGroup_MultiPos;
// Set third group units behavior.
[_group3, [12130.6,2448.48,0], _difficulty, "SAFE"] call DMS_fnc_SetGroupBehavior;
// Remove all previous waypoints for the third group.
for "_i" from count (waypoints _group3) to 1 step -1 do
{
    deleteWaypoint ((waypoints _group3) select _i);
};
// Set third group formation.
//_group3 setFormation "COLUMN";
// Give third group waypoints.
private _wp3 = _group3 addWaypoint [[12130.6,2448.48,0],0];
_wp3 setWaypointType "SENTRY";

// Fourth AI Group spawn.
_group4 = [_AISoldierSpawnLocations4, _AICount4, _difficulty, "sniper", _side] call DMS_fnc_SpawnAIGroup_MultiPos;
// Set fourth group units behavior.
[_group4, [12188.5,2456.66,3.14114], _difficulty, "SAFE"] call DMS_fnc_SetGroupBehavior;
// Remove all previous waypoints for the fourth group.
for "_i" from count (waypoints _group4) to 1 step -1 do
{
    deleteWaypoint ((waypoints _group4) select _i);
};
// Give fourth group waypoints.
private _wp4 = _group4 addWaypoint [[12188.5,2456.66,3.14114],0];
_wp4 setWaypointType "HOLD";
// Let the Ai dont move from there positions.
doStop (units _group4);

// Fifth AI Group spawn.
_group5 = [_AISoldierSpawnLocations5, _AICount5, _difficulty, "assault", _side] call DMS_fnc_SpawnAIGroup_MultiPos;
// Set fifth group units behavior.
[_group5, [12127.8,2493.16,0], _difficulty, "SAFE"] call DMS_fnc_SetGroupBehavior;
// Remove all previous waypoints for the fifth group.
for "_i" from count (waypoints _group5) to 1 step -1 do
{
    deleteWaypoint ((waypoints _group5) select _i);
};
// Set fifth group formation.
//_group5 setFormation "COLUMN";
// Give fifth group waypoints.
private _wp5 = _group5 addWaypoint [[12127.8,2493.16,0],0];
_wp5 setWaypointType "SENTRY";

// Sixth AI Group spawn.
_group6 = [_AISoldierSpawnLocations6, _AICount6, _difficulty, "MG", _side] call DMS_fnc_SpawnAIGroup_MultiPos;
// Set sixth group units behavior.
[_group6, [12184.4,2567.41,17.8731], _difficulty, "SAFE"] call DMS_fnc_SetGroupBehavior;
// Remove all previous waypoints for the sixth group.
for "_i" from count (waypoints _group6) to 1 step -1 do
{
    deleteWaypoint ((waypoints _group6) select _i);
};
// Set sixth group formation.
//_group6 setFormation "COLUMN";
// Give sixth group waypoints.
private _wp6 = _group6 addWaypoint [[12184.4,2567.41,17.8731],0];
_wp6 setWaypointType "SENTRY";

// Seventh AI Group spawn.
_group7 = [_AISoldierSpawnLocations7, _AICount7, _difficulty, "assault", _side] call DMS_fnc_SpawnAIGroup_MultiPos;
// Set seventh group units behavior.
[_group7, [12034.6,2558.85,3.12652], _difficulty, "SAFE"] call DMS_fnc_SetGroupBehavior;
// Remove all previous waypoints for the seventh group.
for "_i" from count (waypoints _group7) to 1 step -1 do
{
    deleteWaypoint ((waypoints _group7) select _i);
};
// Set seventh group formation.
//_group7 setFormation "COLUMN";
// Give seventh group waypoints.
private _wp7 = _group7 addWaypoint [[12034.6,2558.85,3.12652],0];
_wp7 setWaypointType "SENTRY";

// Eighth AI Group spawn.
_group8 = [_AISoldierSpawnLocations8, _AICount8, _difficulty, "sniper", _side] call DMS_fnc_SpawnAIGroup_MultiPos;
// Set eighth group units behavior.
[_group8, [12106.2,2516.74,4.57695], _difficulty, "SAFE"] call DMS_fnc_SetGroupBehavior;
// Remove all previous waypoints for the eighth group.
for "_i" from count (waypoints _group8) to 1 step -1 do
{
    deleteWaypoint ((waypoints _group8) select _i);
};
// Give eighth group waypoints.
private _wp8 = _group8 addWaypoint [[12106.2,2516.74,4.57695],0];
_wp8 setWaypointType "HOLD";
// Let the Ai dont move from there positions.
doStop (units _group8);

// Ninth AI Group spawn.
_group9 = [_AISoldierSpawnLocations9, _AICount9, _difficulty, "MG", _side] call DMS_fnc_SpawnAIGroup_MultiPos;
// Set ninth group units behavior.
[_group9, [12020.3,2447.49,0], _difficulty, "SAFE"] call DMS_fnc_SetGroupBehavior;
// Remove all previous waypoints for the ninth group.
for "_i" from count (waypoints _group9) to 1 step -1 do
{
    deleteWaypoint ((waypoints _group9) select _i);
};
// Set ninth group formation.
//_group9 setFormation "COLUMN";
// Give ninth group waypoints.
private _wp9 = _group9 addWaypoint [[12020.3,2447.49,0],0];
_wp9 setWaypointType "HOLD";

// Patrol AI Group spawn.
_groupPatrol = [_AISoldierSpawnLocationsPatrol, _AICountPatrol, _difficulty, "assault", _side] call DMS_fnc_SpawnAIGroup_MultiPos;
// Set patrol group units behavior.
[_groupPatrol, [12163.8,2547.64,0], _difficulty, "SAFE"] call DMS_fnc_SetGroupBehavior;
// Remove all previous waypoints for the patrol group.
for "_i" from count (waypoints _groupPatrol) to 1 step -1 do
{
    deleteWaypoint ((waypoints _groupPatrol) select _i);
};
// Set the patrol groups formation.
_groupPatrol setFormation "LINE";
// Give patrol group waypoints.
private _wpPatrol1 = _groupPatrol addWaypoint [[12163.8,2547.64,0],0];
_wpPatrol1 setWaypointType "MOVE";
private _wpPatrol2 = _groupPatrol addWaypoint [[12063.6,2525.75,0],0];
_wpPatrol2 setWaypointType "MOVE";
private _wpPatrol3 = _groupPatrol addWaypoint [[12046.3,2492.4,0],0];
_wpPatrol3 setWaypointType "MOVE";
private _wpPatrol4 = _groupPatrol addWaypoint [[12006.7,2468.5,0],0];
_wpPatrol4 setWaypointType "MOVE";
private _wpPatrol5 = _groupPatrol addWaypoint [[12053.9,2403.1,0],0];
_wpPatrol5 setWaypointType "MOVE";
private _wpPatrol6 = _groupPatrol addWaypoint [[12158.4,2470.57,0],0];
_wpPatrol6 setWaypointType "MOVE";
private _wpPatrol7 = _groupPatrol addWaypoint [[12158.4,2470.57,0],0];
_wpPatrol7 setWaypointType "CYCLE";

// Heli AI Group spawn.
// On this npcs location the heli reinfocements will nearly dropp the units.
_groupHeli = [_AISoldierSpawnLocationsHeli, _AICountHeli, _difficulty, "assault", _side] call DMS_fnc_SpawnAIGroup_MultiPos;
// Set ninth group units behavior.
[_groupHeli, [12086.5,2470.26,0], _difficulty, "SAFE"] call DMS_fnc_SetGroupBehavior;
// Remove all previous waypoints for the ninth group.
for "_i" from count (waypoints _groupHeli) to 1 step -1 do
{
    deleteWaypoint ((waypoints _groupHeli) select _i);
};
// Set heli group formation.
//_groupHeli setFormation "COLUMN";
// Give heli group waypoints.
private _wpHeli = _groupHeli addWaypoint [[12086.5,2470.26,0],0];
_wpHeli setWaypointType "HOLD";

// Static Guns
_staticGuns =
[
    [
        [12031.4,2428.87,0.000761271],
        [12148.2,2508.84,2.78],
        [12128.8,2469.37,2.78],
        [12069.4,2461.54,0]
    ],
    _group1,
    "assault",
    _difficulty,
    "bandit",
    "random"
] call DMS_fnc_SpawnAIStaticMG;

DMS_ai_use_launchers = _temp;

// Get the AI to shut the fuck up :)
enableSentences false;
enableRadio false;

// Define mission-spawned AI Units
_missionAIUnits =
[
    [_group1,_group2,_group3,_group4,_group5,_group6,_group7,_group8,_group9,_groupPatrol,_groupHeli]
];

// Define the group reinforcements
_groupReinforcementsInfo =
[
    [
        _groupHeli,                                // pass the group
        [
            [
                _AIMaxReinforcementsWaves,        // Amount of reinfocements waves (defined in difficulty selection).
                0
            ],
            [
                _AIMaxReinforcements,            // Maximum units that can be given as reinforcements (defined in difficulty selection).
                0
            ]
        ],
        [
            _AIdelay,                            // The delay between reinforcements. >> you can change this in difficulty settings
            diag_tickTime
        ],
        _AISoldierSpawnLocationsHeli,
        "random",
        _difficulty,
        _side,
        "heli_troopers",                                // STRING: How the AI group should be managed. Supported types: "playernear", "maintain", "reinforce", "increasing_resistance", "armed_vehicle"
        [
            3,                                            // SCALAR: If the AI Group has fewer than "_AICount" living units, then the group will receive reinforcements.
            "false",                                       // BOOLEAN: Whether or not to eject Fire-From-Vehicle (FFV) gunners.
            5,                                            // SCALAR: Maximum number of AI to eject from the aircraft. Set to a really high # to ignore (like 999).
            "false",                                       // BOOLEAN: Whether or not to keep the heli flying around as a gunship.
            [12141.1,2498.89,0],                           // OBJECT or ARRAY (OPTIONAL - Position2D or 3D): The location to drop the reinforcements at. The drop point will default to the group leader.
            "Exile_Chopper_Huey_Armed_Desert"             // STRING (OPTIONAL): The classname of the heli to spawn.
        ]
    ]
];

// Add mission objects to monitor.
_missionObjs =
[
    [_staticGuns,_missionAIUnits],                            // static gun(s). Note, we don't add the base itself because it already spawns on server start.
    [],                                                        // No Vehicle prize
    []                                                        // Crate price setup (Example: [[_crate,_crate_loot_values]])
];

// Define Mission Start message
_msgStart = ['#FFFF00',"Bandis captured the fortress ruins near Lijnhaven. Pick up your mates and find out what's going on."];

// Define Mission Win message defined in vehicle choice
_msgWIN = ['#0080FF',"Convicts have successfully raided the fortress base!"];

// Define Mission Lose message
_msgLOSE = ['#FF0000',"The bandits have left the fortess and stealed the sensitive technologies."];

// Define mission name (for map marker and logging)
_missionName = "The Fortress";

// Create Markers
_markers =
[
    _pos,
    _missionName,
    _difficulty
] call DMS_fnc_CreateMarker;

_circle = _markers select 1;
_circle setMarkerDir 0;
_circle setMarkerSize [150,150];

_time = diag_tickTime;

// Parse and add mission info to missions monitor
_added =
[
    _pos,
    [
        [
            "kill",
            [_group1,_group2,_group3,_group4,_group5,_group6,_group7,_group8,_group9,_groupPatrol,_groupHeli]
        ],
        [
            "playerNear",
            [_pos,200]
        ]
    ],
    _groupReinforcementsInfo,
    [
        _time,
        DMS_StaticMissionTimeOut call DMS_fnc_SelectRandomVal
    ],
    _missionAIUnits,
    _missionObjs,
    [_missionName,_msgWIN,_msgLOSE],
    _markers,
    _side,
    _difficulty,
    [[],[]]
] call DMS_fnc_AddMissionToMonitor_Static;

// Add the index array to the mission to call a mission comlpetion after player has succesfull destroyed the fortress.
// Just needed if players dont kill all AI.
My_Custom_DMS_Mission_Index = (count DMS_StaticMission_Arr) - 1;

// Check to see if it was added correctly, otherwise delete the stuff
if !(_added) exitWith
{
    diag_log format ["DMS ERROR :: Attempt to set up mission %1 with invalid parameters for DMS_fnc_AddMissionToMonitor_Static! Deleting mission objects and resetting DMS_MissionCount.",_missionName];

    _cleanup = [];
    {
        _cleanup pushBack _x;
    } forEach _missionAIUnits;

    _cleanup pushBack ((_missionObjs select 0)+(_missionObjs select 1));
    
    {
        _cleanup pushBack (_x select 0);
    } foreach (_missionObjs select 2);

    _cleanup call DMS_fnc_CleanUp;

    // Delete the markers directly
    {deleteMarker _x;} forEach _markers;

    // Reset the mission count
    DMS_MissionCount = DMS_MissionCount - 1;
};

// Notify players
[_missionName,_msgStart] call DMS_fnc_BroadcastMissionStatus;

if (DMS_DEBUG) then
{
    (format ["MISSION: (%1) :: Mission #%2 started at %3 with %4 AI units and %5 difficulty at time %6",_missionName,_num,_pos,_AICount,_difficulty,_time]) call DMS_fnc_DebugLog;
};

cheers

1 person likes this

Share this post


Link to post
Share on other sites
Advertisement

well I think I fixed this mission heli, the rest did work when someone was testing it for me but as no development server if anyone wants to try this mission called "George Town" as its a mass invasion of George Town with roof top snipers, waves of armed vehicle, roadblocks on mission start and all sorts of other stuff for Tanoa, then let me know and I will give you the files.

It is the most complex mission I have attempted but you will need to know it is beta, but if I can get it fully working then I can do a few other missions people requested.

cheers

 

Features
1. Road blocks spawn on mission start and get cleared up after.
2. Mission available in 4 difficulties.
3. Full control of reinforcement settings. v2.1 code.
4. Randomised loot with cash loaded into crates
5. Separate ground AI to building top sniper AI.
6. AI vehicle patrol will reinforce to different locations in the town.
7. Ground AI reinforce but snipers don't.
8. % chance of permanent heli prize.
9. Added random amounts of poptabs to crates for prize.
10. Heli reinforcements with gunship

1 person likes this

Share this post


Link to post
Share on other sites

Hi @red_ned

Unfortunately my server is Cherno, but I would love to check out how you got heli reinforcements to work.

My problem is that the heli pilot is included as part of the mission ai. If you dont take out the heli, the mission doesn't end and sometime the heli goes walkabout.

@[AI] Stalker suggested I might need to call them in a different group.

Any suggestions would be much appreciated.

cheers

Share this post


Link to post
Share on other sites

@aussie battler I created another group for the heli and made sure not to include in the mission count/triggers

Quote

// Define mission-spawned AI Units
_missionAIUnits = [
      _group,   // Main AI
      _group2   // Snipers
      //_group3  //heli - if not included in the mission triggers and it wanders off it mission should still complete
     ];

As I said I haven't tested yet so not 100% it works yet and I may just publish the mission as beta until someone verifies it works as I spent a load of time last year putting it together and didn't release just due to the heli

1 person likes this

Share this post


Link to post
Share on other sites

Hey @red_ned

I'm happy to test it on Cherno if you dont mind me doing a different lot of objects for Cherno.

I like the looks of your new money mission :)


cheers

Share this post


Link to post
Share on other sites

@aussie battler it is a static mission so would take a lot of reworking for another map due to all the statically placed AI but if you want to test out the code then I can let you have a copy to hack up for your map

Share this post


Link to post
Share on other sites

Not a problem, I'm happy to give it a go. I ported your comms alpha mission for Tanoa to Cherno. I loved that mission, unfortunatly our Tanoa server had no players. :(

Share this post


Link to post
Share on other sites

Hey @red_ned

That is one hardcore mission that you made, great work. I have not tested this on Tanoa only on Cherno.

I get this error when the Ai heli reinforcement is suppose to be called:

 

Spoiler

Error in expression <lass = if ((count _this)>8) then {_this param [8, "", [""]]} else {selectRandom >
  Error position: <param [8, "", [""]]} else {selectRandom >
  Error Type Array, expected String
File x\addons\dms\scripts\fn_SpawnHeliReinforcement.sqf, line 47
Error in expression <Pos =
if ((count _this)>9) then
{
_this param [9, [0,0,0], [[]], [2,3]]
}
else
{>
  Error position: <param [9, [0,0,0], [[]], [2,3]]
}
else
{>
  Error 1 elements provided, 2 expected
File x\addons\dms\scripts\fn_SpawnHeliReinforcement.sqf, line 60
Cannot create non-ai vehicle ,
"DMS ERROR :: Null _heli in DMS_HeliParatrooper_Arr (index 0). Parameters: [<NULL-object>,[[10214.5,2647.51,0]],""true""]"
UH1H_Skeleton: Invalid parent bone 'damagehide' for 'glass1'
UH1H_Skeleton: Invalid parent bone 'damagehide' for 'glass4'
UH1H_Skeleton: Invalid parent bone 'damagehide' for 'glass5'
Warning: Convex component representing Skids not found
Array mat in bin\config.bin/CfgVehicles/UH1HL_base/Damage/ not multiply of 3
Exile_Chopper_Huey_Desert: Glass7_destruct - unknown animation source HitGlass7
Error: bin\config.bin/CfgVehicles/UH1H_Clo/Turrets/MainTurret/: Turret body NewTurret not found while initializing the model exile_psycho_uh1h\uh1h_closed.p3d
Error: bin\config.bin/CfgVehicles/UH1H_Clo/Turrets/MainTurret/: Turret gun mainGun not found while initializing the model exile_psycho_uh1h\uh1h_closed.p3d

Everything spawns in and the loot crates work. 

Ill try & mix another heli reinforcement call in to see if it works.

cheers

Edited by aussie battler
1 person likes this

Share this post


Link to post
Share on other sites

I can get the heli reinforcements to work by:

Comment out line 121 to 128:

Spoiler

/**

define heli start, drop and class
_spawnPos    =    [10283.199,3351,350];
_dropPoint    =    [10214.5,2647.51,0];
_heliClass    =    ["Exile_Chopper_Huey_Armed_Green"];

 **/

change your heli code to this (thanks to @eraser1 for the code:

Spoiler

_group3    =    [                                                        // Helicopter support group
                //heli reinforcements
    _pos,
    1,
    "random",
    "random",
    "bandit"
] call DMS_fnc_SpawnAIGroup;
[
    _group3,
    "random",
    "difficult",
    "bandit",
    _pos,
    true,
    5,
   false,
    "Exile_Chopper_Huey_Armed_Green"
] call DMS_fnc_SpawnHeliReinforcement;

// Check to see if it was added correctly, otherwise delete the stuff (ends above this line)

If I chose the option not to eject the gunners & the heli remains as a gunship the heli is still part of the mission. The mission can't be completed until the heli is taken out. Currently the heli does a fly by, drops the reinforcement and then dissapears off the map.

 

Edited by aussie battler
1 person likes this

Share this post


Link to post
Share on other sites
Advertisement

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now

  • Recently Browsing   0 members

    No registered users viewing this page.