• 0
Admiral EliteSuicide

[SOLVED] Insert and Edit Aircraft Carrier

Question

Hey Guys, 

I have an Problem to edit the USS on my Server.

I placed the USS perfect in Editor and saved the koordinations, but on my Server the Aircraft Carrier looks not good 

107410_screenshots_20170527035838_1.jpg

I tried to edit the Koordinations on Server but nothing changes and the Aircraft Carrier still stand like on the picture..

Desktop 05.27.2017 - 04.04.39.04.png

 

Someone have an Idea to get the Aircraft Carrier good ? :)

Edited by Admiral EliteSuicide

Share this post


Link to post
Share on other sites

7 answers to this question

  • 0

There is a few ways of doing this but i add the carrier this way catapult don't work though

if (isServer) then {
    private _carrier = createVehicle ["Land_Carrier_01_base_F",[4530.19, 1427.48, 292.950],[],0,"NONE"];
    _carrier setPosWorld [4530.19, 1427.48, 0]; // [x,y,z] or positionWorld
    _carrier setDir 117; // West
    _carrier enableSimulationGlobal true;    
    [_carrier] call BIS_fnc_Carrier01PosUpdate;
};

add to initServer.sqf

Share this post


Link to post
Share on other sites
Advertisement
  • 0

I would add it in through the Mission.sqm, catapult works fine. and all the lights (night time) work as well. 

Share this post


Link to post
Share on other sites
  • 0
On 5/28/2017 at 0:11 AM, Dead Pool said:

I would add it in through the Mission.sqm, catapult works fine. and all the lights (night time) work as well. 

give me an example to add to your mission.sqm

just so i know im adding it correctly

Share this post


Link to post
Share on other sites
  • 0

mine works with catapults etc

STEP 1. Copy the code below and use notepad++ to paste it and save as spawnCarrier.sqf and put the file in mpmissions exile.altis folder, if using altis, this is where your initserver.sqf , init.sqf files live......


if (isServer) then {
diag_log ":: Spawning Carrier";
//  Spawn Carrier
private _obj = ["Land_Carrier_01_base_F", [13261.5, 14312.7, -2.2], [080.031, 0.0417459, 0], [0, 0, 1], true];
private _vehicle = (_obj select 0) createVehicle (_obj select 1);
_vehicle allowDamage false;
_vehicle setPosWorld (_obj select 1);
_vehicle setVectorDirAndUp [_obj select 2, _obj select 3];
[_vehicle] call BIS_fnc_Carrier01PosUpdate;

// Broadcast Carrier ID over network
missionNamespace setVariable ["USS_FREEDOM_CARRIER",_vehicle]; publicVariable "USS_FREEDOM_CARRIER";
_vehicle enableSimulationGlobal true;

} else {
	[] spawn {
		// Clients wait for carrier
		waitUntil { !(isNull (missionNamespace getVariable ["USS_FREEDOM_CARRIER",objNull])) };

		// Work around for missing carrier data not being broadcast as expected
		if (count (USS_FREEDOM_CARRIER getVariable ["bis_carrierParts", []]) == 0) then {
			["Carrier %1 is empty. Client Fixing.",str "bis_carrierParts"] call BIS_fnc_logFormatServer;
			private _carrierPartsArray = (configFile >> "CfgVehicles" >> typeOf USS_FREEDOM_CARRIER >> "multiStructureParts") call BIS_fnc_getCfgDataArray;
			private _partClasses = _carrierPartsArray apply {_x select 0};
			private _nearbyCarrierParts = nearestObjects [USS_FREEDOM_CARRIER,_partClasses,500];
			{
				private _carrierPart = _x;
				private _index = _forEachIndex;
				{
					if ((_carrierPart select 0) isEqualTo typeOf _x) exitWith { _carrierPart set [0,_x]; };
				} forEach _nearbyCarrierParts;
				_carrierPartsArray set [_index,_carrierPart];
			} forEach _carrierPartsArray;
			USS_FREEDOM_CARRIER setVariable ["bis_carrierParts",_nearbyCarrierParts];
			["Carrier %1 was empty. Now contains %2.",str "bis_carrierParts",USS_FREEDOM_CARRIER getVariable ["bis_carrierParts", []]] call BIS_fnc_logFormatServer;
		};

		// Client Initiate Carrier Actions with slight delay to ensure carrier is sync'd
		[USS_FREEDOM_CARRIER] spawn { sleep 1; _this call BIS_fnc_Carrier01Init};
	};
};

STEP 2.  goto your mpmissions exile altis folder and open your init.sqf file or create one using notepad++ and copy and paste the following code shown below. When you are finished pbo as usual and restart server.

[] execVM "spawnCarrier.sqf";

 

Share this post


Link to post
Share on other sites
Advertisement

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now

  • Recently Browsing   0 members

    No registered users viewing this page.