Sign in to follow this  
sjJACKit

How to reduce personal Waypoints from 5 to X?

5 posts in this topic

Dont know if u can change the total numbers of waypoints but u can change the ability to set them or not.

By the way...why u want to reduce the waypoints to 3? Waypoints or no waypoints...that make sense i guess :rock:

Share this post


Link to post
Share on other sites
Advertisement

Actually I want to reduce them to one. But then I came up with the idea to give one extra in order to e. g. mark 2 missions that spawn close to each other and what not. I wrote 3 just an example.

Five WP just go on my nerves really.

I come from a time where no WPs at all were available, but that would be a bit harsh in current casualized player base and considering the fact that there are way more than just one chernarus map to learn and remember

 

Another thing:

In

https://community.bistudio.com/wiki/Arma_3_Difficulty_Menu

I found 

                        tacticalPing = 1;       //Tactical Ping (0 = disabled, 1 = enabled)

Any idea what that is?

 

Share this post


Link to post
Share on other sites

Got help from Kuplion with an override. I wanna share that here, so that others can have access too. All credits to kuplion ofc.

ExileClient_gui_map_event_onMouseButtonUp.sqf
Content:

Spoiler

/**
 * ExileClient_gui_map_event_onMouseButtonUp
 *
 * Exile Mod
 * www.exilemod.com
 * © 2015 Exile Mod Team
 *
 * Modified by [FPS]kuplion
 *
 * This work is licensed under the Creative Commons Attribution-NonCommercial-NoDerivatives 4.0 International License. 
 * To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-nd/4.0/.
 */
 
private["_mapControl","_mouseButton","_position","_shift","_ctrl","_alt","_stopPropagation","_maxLines","_control","_buttonControl","_statusControl","_colorDropdown","_render","_color","_renderPosition","_lines","_count","_text","_linesLabel","_linesStatus","_clickPosition","_display","_contextControl"];
_mapControl = _this select 0;
_mouseButton = _this select 1;
_position = [_this select 2,_this select 3];
_shift = _this select 4;
_ctrl = _this select 5;
_alt = _this select 6;
_stopPropagation = false;
if (ExileClientMapPolyMode) then
{
    _maxLines = getNumber(missionConfigFile >> "CfgClans" >> "maximumPolyNode");
    _control = uiNamespace getVariable ["RscExileMapCreatePoly",controlNull];
    _buttonControl = _control controlsGroupCtrl 4002;
    _statusControl = _control controlsGroupCtrl 4001;
    _colorDropdown = _control controlsGroupCtrl 4000;
    if(_mouseButton isEqualTo 0)then
    {
        if((count ExileClientClanMapLineRenderArray) < _maxLines)then
        {
            if(!ExileClientClanMapLineCompleated)then
            {
                _render = [];
                _color = (_colorDropdown lbColor (lbCursel _colorDropdown));
                _renderPosition = _mapControl ctrlMapScreenToWorld _position;
                _renderPosition pushback 0;
                if(_renderPosition call ExileClient_gui_clan_polyAddMenu_isCompleatedPoly)then
                {
                    _buttonControl ctrlEnable true;
                    _buttonControl ctrlCommit 0;
                    _statusControl ctrlSetBackGroundColor [160/255, 223/255, 59/255, 1];
                    _statusControl ctrlCommit 0;
                    _render = [ExileClientLineLastRenderPos,((ExileClientClanMapLineRenderArray select 0) select 0),_color];
                    ExileClientClanMapLineRenderArray pushback _render;
                    ExileClientClanMapLineCompleated = true;
                }
                else
                {
                    if(ExileClientLineLastRenderPos isEqualTo [0,0,0])then
                    {
                        _colorDropdown ctrlEnable false;
                    }
                    else
                    {
                        _render = [ExileClientLineLastRenderPos,_renderPosition,_color];
                        ExileClientClanMapLineRenderArray pushback _render;
                    };
                    ExileClientLineLastRenderPos = _renderPosition;
                };
            };
        }
        else
        {
            _buttonControl ctrlEnable false;
            _buttonControl ctrlCommit 0;
        };
    }
    else
    {
        if(ExileClientLastMapDown + 0.1 > diag_tickTime)then
        {
            _lines = count ExileClientClanMapLineRenderArray;
            if(_lines > 0)then
            {
                if(ExileClientClanMapLineCompleated)then
                {
                    _buttonControl ctrlEnable false;
                    _buttonControl ctrlCommit 0;
                    _statusControl ctrlSetBackGroundColor [221/255, 38/255, 38/255, 1];
                    _statusControl ctrlCommit 0;
                    ExileClientClanMapLineCompleated = false;
                };
                if(count ExileClientClanMapLineRenderArray > 1)then
                {
                    ExileClientLineLastRenderPos = (ExileClientClanMapLineRenderArray select (_lines - 1)) select 0;
                }
                else
                {
                    _colorDropdown ctrlEnable true;
                    ExileClientLineLastRenderPos = [0,0,0];
                };
                ExileClientClanMapLineRenderArray deleteAt (_lines -1);
            };
        };
    };
    _count = count ExileClientClanMapLineRenderArray;
    _text = format ["%1/%2",_count,_maxLines];
    _linesLabel = _control controlsGroupCtrl 4004;
    _linesLabel ctrlSetText _text;
    _linesLabel ctrlCommit 0;
    _linesStatus = _control controlsGroupCtrl 4003;
    _linesStatus progressSetPosition (_count/_maxLines);
    _linesStatus ctrlCommit 0;
}
else
{
    switch (_mouseButton) do 
    {
        case 0:
        {
            if (_shift) then
            {
                _clickPosition = _mapControl ctrlMapScreenToWorld _position;
                _clickPosition pushBack 0;
                ExileClientWaypoints pushBack _clickPosition;
                if ((count ExileClientWaypoints) > 2) then ///////////////////////////////////////////////////// Number = Max Waypoints
                {
                    ExileClientWaypoints deleteAt 0;
                };
                _stopPropagation = true;
            };
        };
        case 1:
        {
            if !(_shift || _alt || _ctrl) then                
            {
                if(ExileClientLastMapDown + 0.1 > diag_tickTime)then
                {
                    _display = ctrlParent _mapControl;
                    if!(ExileClientClanInfo isEqualTo [])then
                    {
                        _contextControl = _display ctrlCreate ["RscExileMapContextMenu",24032];
                        _contextControl ctrlSetPosition _position;
                        _contextControl ctrlCommit 0;
                    };
                    ExileClientMapPositionClick = _mapControl ctrlMapScreenToWorld _position;
                    ExileClientMapScreenPos = _position;
                };
            };
            _stopPropagation = true;
        };
    };
};
_stopPropagation

put 
ExileClient_gui_map_event_onMouseButtonUp = "overrides\ExileClient_gui_map_event_onMouseButtonUp.sqf";

into mission file config.cpp ==> class CfgExileCustomCode

Again thanks to kuplion, I am just releasing it here as he is probably too busy to do that.

Edited by sjJACKit

Share this post


Link to post
Share on other sites
Advertisement

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this  

  • Recently Browsing   0 members

    No registered users viewing this page.