• 0
Sign in to follow this  
Neorax

XM8 (ExAd) Bug

Question

Hello guys I installed the ExAd for 1.0.4 

 

Everything works fine except when I open an App with GUI for example Health Scanner and then close XM8 (6 or ESC does not matter) and I reopen the XM8 I get a blank screen without any buttons.

I would then have to relog to use the XM8 normaly again.

Someone please help me im going insane rn....

If needed I can provide rpt logs and config.cpp etc.

Share this post


Link to post
Share on other sites

2 answers to this question

  • 0
On 29. 6. 2018 at 10:07 AM, Neorax said:

Hello guys I installed the ExAd for 1.0.4 

 

Everything works fine except when I open an App with GUI for example Health Scanner and then close XM8 (6 or ESC does not matter) and I reopen the XM8 I get a blank screen without any buttons.

I would then have to relog to use the XM8 normaly again.

Someone please help me im going insane rn....

If needed I can provide rpt logs and config.cpp etc.

I have same problem...

Share this post


Link to post
Share on other sites
  • 0

maybe you use an old version of the ExAdClient\XM8\CustomCode\ExileClient_gui_xm8_show.sqf file.

Try this version:

Spoiler

/**
 * ExileClient_gui_xm8_show
 *
 * Exile Mod
 * www.exilemod.com
 * © 2015 Exile Mod Team
 *
 * This work is licensed under the Creative Commons Attribution-NonCommercial-NoDerivatives 4.0 International License.
 * To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-nd/4.0/.
 */
 
private["_display", "_control", "_slideControlID", "_slideName", "_slideTitle", "_slideControl", "_appID", "_resource", "_slidesControlGroup", "_titleControl", "_toSlideOpenFunction"];
disableSerialization;
createDialog "RscExileXM8";
ExileClientXM8IsVisible = true;
_display = uiNameSpace getVariable ["RscExileXM8", displayNull];
if (ExileClientXM8IsPowerOn) then
{
    _control = _display displayCtrl 4002;
    _control ctrlSetFade 1;
    _control ctrlCommit 0;
}
else
{
    {
        _control = _display displayCtrl _x;
        _control ctrlSetFade 1;
        _control ctrlCommit 0;
    }
    forEach
    [
        4002,
        4003,
        4004,
        4005,
        4007,
        4001,
        4010,
        4030,
        4020        
    ];
};
true call ExileClient_gui_postProcessing_toggleDialogBackgroundBlur;
if (ExileClientXM8CurrentSlide isEqualTo "party") then
{
    if (ExileClientPartyID isEqualTo -1) then
    {
        ExileClientXM8CurrentSlide = "apps";
    };
};

//Add configured controls and add them to "More"
call ExAd_fnc_createExtraApps;

{
    _slideControlID = getNumber (_x >> "controlID");
    _slideName = configName _x;
    _slideTitle = getText (_x >> "title");
    _slideControl = _display displayCtrl _slideControlID;
    if (_slideName isEqualTo ExileClientXM8CurrentSlide) then
    {
        if (isNull _slideControl) then
        {
            _appID = getText(_x >> "appID");
            _resource = getText(missionConfigFile >> format["XM8_%1_Button", _appID] >> "resource");
            _slidesControlGroup = _display displayCtrl 4007;
            _slideControl = _display ctrlCreate [_resource, getNumber(missionConfigFile >> _resource >> "idc"), _slidesControlGroup];
        };
        _titleControl = _display displayCtrl 4004;
        _titleControl ctrlSetStructuredText (parseText (format ["<t align='center' font='RobotoMedium'>%1</t>", _slideTitle]));
        _slideControl ctrlSetPosition [(0 * 0.05), (0 * 0.05)];
        _slideControl ctrlCommit 0;
        _slideControl ctrlShow true;
        _toSlideOpenFunction = missionNamespace getVariable [format ["ExileClient_gui_xm8_slide_%1_onOpen", _slideName], ""];
        if !(_toSlideOpenFunction isEqualTo "") then
        {
            call _toSlideOpenFunction;
        };
    }
    else
    {
        if !(isNull _slideControl) then
        {
            _slideControl ctrlShow false;
        };
    };
}
forEach (("true" configClasses (missionConfigFile >> "CfgXM8")) + ("true" configClasses (configFile >> "CfgXM8")));
ExileXM8ThreadHandle = [10, ExileClient_gui_xm8_thread_update, [], true] call ExileClient_system_thread_addtask;
call ExileClient_gui_xm8_thread_update;

And I think there is no need to use the ExAdClient\XM8\CustomCode\ExileClient_gui_xm8_slide.sqf file any longer.

  • Like 1

Share this post


Link to post
Share on other sites
Advertisement

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this  

  • Recently Browsing   0 members

    No registered users viewing this page.